Copy File Link to Clipboard (Win32)

' File Name: CopyWikiLink.vbs
' Purpose:
'   This is a self-installing (and un-installing) script that adds a context
'   sensitive menu to Windows Explorer.  When the menu choice is chosen
'   it copies a string to the Windows Clipboard that is a link to the chosen
'   file (or folder) formatted appropriately for the Confluence Wiki.
'
' Installation Notes:
'   1. Make sure that the file extension is .vbs if it has been changed
'   2. Put this file somewhere where you can leave it (eg: C:/Windows)
'   3. Execute the file (eg: double-click it in Explorer)
'   4. Read the directions!
'
' Notes:
'  - Verified on XP and *should* work with Win2000
'  - Had to resort to some voodoo to get the clipboard with a vbs... not sure
'    that the voodoo will last, although it has for a few years.
'  - This would be easier with an exe, but tried with a script mostly for kicks
'
' File History:
' 06-02-04 russ  Created first release

Option Explicit
Dim fso, ws, Args
Set fso = CreateObject("Scripting.FileSystemObject")
Set ws = CreateObject("Wscript.Shell")
Set Args = WScript.Arguments

Sub CopyTextToClipboard(msg)
	'This is a wacky trick to get through VBScript "security"
	'to get something into the clipboard...  might be more
	'than a bit slow for my liking
	dim oIE
	Set oIE = CreateObject("InternetExplorer.Application")
	oIE.Navigate "about:blank"
	Do Until oIE.ReadyState=4: WScript.Sleep 1: Loop
	oIE.Document.ParentWindow.ClipboardData.SetData "Text", msg
	oIE.Quit 
End Sub

Sub SetContextMenu(ContextTypeString, MenuText, CommandString)
  'Some examples for ContextTypeString are:
  '     "*" for all file types
  '     ".ext" for a particular extension (ext in this case)
  '     "jpegfile" for an extension group (.jpg, .jpeg, etc in this case)
  '         - to see the appropriate group name for an extension, check
  '           the default value in the \HKCR\.ext (eg: \HKCR\.jpg) value
  '     "Folder" for directories/folders
  Dim regPath

  regPath = "HKCR\" & ContextTypeString & "\shell\" & MenuText & "\"
  ws.RegWrite regPath & "command\", CommandString
End Sub

Sub ClearContextMenu(ContextTypeString, MenuText)
  'See SetContextMenu for examples
  Dim regPath
  regPath = "HKCR\" & ContextTypeString & "\shell\" & MenuText & "\"
  ws.RegDelete regPath & "command\"
  ws.RegDelete regPath
End Sub

Function GetContextCommand(ContextTypeString, MenuText)
  'See SetContextMenu for examples
  'Returns "" if no command
  Dim regPath
  Dim cmdString
  regPath = "HKCR\" & ContextTypeString & "\shell\" & MenuText & "\"

  On Error Resume Next
  cmdString = ""
  cmdString = ws.RegRead(regPath & "command\")
  'MsgBox "For path """ & regPath & """" & vbcrlf & "Cmd = " & cmdString
  Err.Clear:On Error GoTo 0
  GetContextCommand = cmdString
End Function

Sub ToggleInstall()
  Dim cmd
  Dim menuName
  Dim scriptName
  Dim menuCmdString
  Dim popupTitle
  
  menuName = "Copy Wiki link to clipboard"
  scriptName = WScript.ScriptFullName
  menuCmdString = "wscript """ & LCase(scriptName) & """ ""%l"""
  popupTitle = """" & menuName & """ Context Menu Tool"
  
  'See if the menu already exists...
  cmd = GetContextCommand("*", menuName)
  If LCase(cmd) = menuCmdString Then
    'we've already defined the menu with this script...
    If ws.Popup("Do you want to un-install the """ & menuName & """ Explorer context menu?" _
	             , , popupTitle, 4 + 32 + 4096) <> 6 Then
      Call Cleanup
    End If
	ClearContextMenu "*", menuName
	ClearContextMenu "Folder", menuName
    ws.Popup "Un-install complete!  The context menu has been removed from Explorer.", , popupTitle, 64 + 4096
  Else
    'no definition yet - install it
    If ws.Popup("Do you want to install the """ & menuName & """ Explorer context menu?" _
	             , , popupTitle, 4 + 32 + 4096) <> 6 Then
      Call Cleanup
    End If
	SetContextMenu "*", menuName, menuCmdString
	SetContextMenu "Folder", menuName, menuCmdString
    ws.Popup "Setup complete!" & vbCrLf & vbCrLf & "You can now right click on any file in Windows " & _
             "Explorer and select the ""Copy wiki link to clipboard"" " & _
             "option to copy a link appropriate for pasting into " & _
			 "Confluence in your clipboard." & vbcrlf & vbcrlf & _
             "To Un-install this (and get rid of the context menu), simply run this script again.", _
             , popupTitle, 64 + 4096
  End If
End Sub

Sub Cleanup
  Set ws = Nothing
  Set fso = Nothing
  Set Args = Nothing
  WScript.Quit
End Sub  

'NOW FOR THE PROGRAM...
Dim argString
Dim i
argString = "ArgCount = " & Args.Count & vbCRLF
for i = 1 to Args.Count
  argString = argString & vbCRLF & Args(i-1)
next
If Args.Count > 1 Then
  'Not sure how this can happen - would like to trap it...
  Msgbox "Args.Count is somehow > 1 (" & Args.Count & ")" & vbcrlf & vbcrlf & argString
  Call Cleanup
End If

'Check how this was invoked...
If Args.Count = 0 Then
  'No args means a direct invokation - either self install or uninstall...
  Call ToggleInstall
  Call Cleanup
End If

'If we get here, we know what to convert and should put it to clipboard...
Dim buf
Dim fName

fName = fso.GetFileName(Args(0))
'msgbox "Fname = " & fName
buf = "[" & fName & "|"
buf = buf & "file:///" & Replace(Args(0),"\","/")
buf = buf & "]"
'msgbox "clip = " & buf
Call CopyTextToClipboard(buf)
Call Cleanup